ABAP /

Limpieza de cachés Fiori / Gateway p.ej. tras copia de mandante

Descripción

Este programa agrupa en una única ejecución las principales tareas estándar de invalidación y regeneración de cachés utilizadas en entornos Fiori. Resulta especialmente útil después de actividades técnicas que puedan dejar información inconsistente en memoria o índices obsoletos, tales como copias de mandante, refreshes de sistemas, copias homogéneas o heterogéneas, importación masiva de órdenes de transporte, actualizaciones de componentes SAP_UI o SAP_GWFND, así como despliegues o actualizaciones de aplicaciones SAPUI5/Fiori.

El objetivo es garantizar que los metadatos OData, los índices de aplicaciones, las definiciones del Launchpad y el contenido almacenado en caché se regeneren correctamente, evitando incidencias habituales como aplicaciones Fiori que no aparecen en el Launchpad, servicios OData que siguen mostrando metadatos antiguos, tiles que no se cargan correctamente o inconsistencias posteriores a una copia de sistema o de mandante.

Todos los programas estándar se ejecutan en modo silencioso (background mode), sin mostrar sus pantallas de selección ni sus listas de salida originales. La ejecución se realiza de forma secuencial mediante SUBMIT ... AND RETURN, capturando internamente el resultado de cada proceso.

Para cada paso ejecutado se registra la siguiente información:

  • Programa ejecutado.
  • Descripción funcional.
  • Hora de inicio.
  • Hora de finalización.
  • Duración de la ejecución.
  • Estado final (Correcto/Error).
  • Mensajes y salida capturada.

Al finalizar se presenta una lista resumen consolidada con todas las operaciones realizadas y el resultado obtenido en cada una de ellas.

Secuencia de ejecución

  1. /IWBEP/R_MGW_MED_CACHE_CLEANUP - (Transacción /IWBEP/CACHE_CLEANUP'''): Elimina la caché de metadatos del framework SAP Gateway Backend (/IWBEP). Se ejecuta para todos los servicios registrados con el fin de obligar a la regeneración de los metadatos OData almacenados.
  2. /IWFND/R_MED_CACHE_CLEANUP - (Transacción /IWFND/CACHE_CLEANUP) : Limpia la caché de metadatos del Gateway Hub (/IWFND), eliminando información almacenada de los servicios OData consumidos por las aplicaciones SAP Fiori.
  3. /UI5/APP_INDEX_CALCULATE: Recalcula el índice de aplicaciones SAPUI5 para todos los repositorios disponibles. La ejecución se realiza en modo "objetos caducados", regenerando únicamente aquellas entradas que requieren actualización y reduciendo así el tiempo total del proceso.
  4. /UI2/INVALIDATE_GLOBAL_CACHES: Invalida las cachés globales de SAP Fiori Launchpad compartidas por todos los usuarios del sistema. Estas cachés se reconstruyen automáticamente bajo demanda durante los siguientes accesos.
  5. /UI2/DELETE_CACHE_AFTER_IMP: Elimina los contenidos de caché asociados a componentes de Launchpad y SAP_UI que puedan haber quedado obsoletos tras una importación de transportes o una copia de sistema. La ejecución se realiza para todos los mandantes existentes.
  6. . /UI2/INVALIDATE_CLIENT_CACHES: Invalida las cachés específicas de cada mandante y usuario, garantizando que catálogos, grupos, espacios, páginas, roles y demás configuraciones del Launchpad se vuelvan a cargar desde la información actualizada del sistema.

Una vez completada la ejecución de todos los pasos, se recomienda que los usuarios cierren las sesiones activas del navegador y vuelvan a iniciar sesión en SAP Fiori para asegurar que utilizan exclusivamente la información regenerada y evitar posibles inconsistencias derivadas de datos cacheados localmente.

  1. REPORT zini_limpieza_fiori LINE-SIZE 180 NO STANDARD PAGE HEADING.
  2.  
  3. *----------------------------------------------------------------------*
  4. * Constantes
  5. *----------------------------------------------------------------------*
  6. CONSTANTS:
  7.   gc_prog_bep    TYPE progname VALUE '/IWBEP/R_MGW_MED_CACHE_CLEANUP',
  8.   gc_prog_fnd    TYPE progname VALUE '/IWFND/R_MED_CACHE_CLEANUP',
  9.   gc_prog_ui5    TYPE progname VALUE '/UI5/APP_INDEX_CALCULATE',
  10.   gc_prog_global TYPE progname VALUE '/UI2/INVALIDATE_GLOBAL_CACHES',
  11.   gc_prog_imp    TYPE progname VALUE '/UI2/DELETE_CACHE_AFTER_IMP',
  12.   gc_prog_client TYPE progname VALUE '/UI2/INVALIDATE_CLIENT_CACHES',
  13.   gc_memid_glob  TYPE char40   VALUE '/UI2/INVALIDATE_GLOBAL_CACHES'.
  14.  
  15. *----------------------------------------------------------------------*
  16. * Pantalla de selección
  17. *----------------------------------------------------------------------*
  18. SELECTION-SCREEN BEGIN OF BLOCK b01 WITH FRAME TITLE gv_tit1.
  19. SELECTION-SCREEN BEGIN OF LINE.
  20. PARAMETERS p_bep AS CHECKBOX DEFAULT abap_true.
  21. SELECTION-SCREEN COMMENT 3(75) gv_tbep FOR FIELD p_bep.
  22. SELECTION-SCREEN END OF LINE.
  23. SELECTION-SCREEN BEGIN OF LINE.
  24. PARAMETERS p_fnd AS CHECKBOX DEFAULT abap_true.
  25. SELECTION-SCREEN COMMENT 3(75) gv_tfnd FOR FIELD p_fnd.
  26. SELECTION-SCREEN END OF LINE.
  27. SELECTION-SCREEN BEGIN OF LINE.
  28. PARAMETERS p_ui5 AS CHECKBOX DEFAULT abap_false.
  29. SELECTION-SCREEN COMMENT 3(75) gv_tui5 FOR FIELD p_ui5.
  30. SELECTION-SCREEN END OF LINE.
  31. SELECTION-SCREEN END OF BLOCK b01.
  32.  
  33. SELECTION-SCREEN BEGIN OF BLOCK b02 WITH FRAME TITLE gv_tit2.
  34. SELECTION-SCREEN BEGIN OF LINE.
  35. PARAMETERS p_global AS CHECKBOX DEFAULT abap_true.
  36. SELECTION-SCREEN COMMENT 3(75) gv_tglo FOR FIELD p_global.
  37. SELECTION-SCREEN END OF LINE.
  38. SELECTION-SCREEN BEGIN OF LINE.
  39. PARAMETERS p_imp AS CHECKBOX DEFAULT abap_true.
  40. SELECTION-SCREEN COMMENT 3(75) gv_timp FOR FIELD p_imp.
  41. SELECTION-SCREEN END OF LINE.
  42. SELECTION-SCREEN BEGIN OF LINE.
  43. PARAMETERS p_client AS CHECKBOX DEFAULT abap_true.
  44. SELECTION-SCREEN COMMENT 3(75) gv_tcli FOR FIELD p_client.
  45. SELECTION-SCREEN END OF LINE.
  46. SELECTION-SCREEN END OF BLOCK b02.
  47.  
  48. *----------------------------------------------------------------------*
  49. * Clase local: limpiador de cachés
  50. *----------------------------------------------------------------------*
  51. CLASS lcl_limpiador DEFINITION FINAL.
  52.   PUBLIC SECTION.
  53.     TYPES:
  54.       BEGIN OF ty_programa,
  55.         programa    TYPE progname,
  56.         descripcion TYPE string,
  57.       END OF ty_programa,
  58.       ty_t_programas TYPE STANDARD TABLE OF ty_programa WITH EMPTY KEY.
  59.  
  60.     METHODS ejecutar
  61.       IMPORTING it_programas TYPE ty_t_programas.
  62.  
  63.   PRIVATE SECTION.
  64.     CONSTANTS:
  65.       gc_estado_ok    TYPE char1 VALUE 'S',
  66.       gc_estado_error TYPE char1 VALUE 'E'.
  67.  
  68.     TYPES:
  69.       BEGIN OF ty_paso,
  70.         programa    TYPE progname,
  71.         descripcion TYPE string,
  72.         estado      TYPE char1,
  73.         mensaje     TYPE string,
  74.         segundos    TYPE p LENGTH 8 DECIMALS 2,
  75.         detalle     TYPE string_table,
  76.       END OF ty_paso,
  77.       ty_t_pasos      TYPE STANDARD TABLE OF ty_paso WITH EMPTY KEY,
  78.       ty_t_parametros TYPE STANDARD TABLE OF rsparams WITH EMPTY KEY.
  79.  
  80.     " Proceso de cada programa
  81.     METHODS procesar_paso
  82.       IMPORTING is_programa    TYPE ty_programa
  83.       RETURNING VALUE(rs_paso) TYPE ty_paso.
  84.     METHODS existe_programa
  85.       IMPORTING iv_programa      TYPE progname
  86.       RETURNING VALUE(rv_existe) TYPE abap_bool.
  87.  
  88.     " Autorizaciones (mismas comprobaciones que hace cada estándar)
  89.     METHODS tiene_autorizacion
  90.       IMPORTING iv_programa  TYPE progname
  91.       RETURNING VALUE(rv_ok) TYPE abap_bool.
  92.     METHODS autorizacion_chip
  93.       RETURNING VALUE(rv_ok) TYPE abap_bool.
  94.     METHODS autorizacion_ui5
  95.       RETURNING VALUE(rv_ok) TYPE abap_bool.
  96.     METHODS autorizacion_gateway
  97.       IMPORTING iv_clase     TYPE seoclsname
  98.                 iv_vista     TYPE viewname
  99.       RETURNING VALUE(rv_ok) TYPE abap_bool.
  100.  
  101.     " Parámetros y lanzamiento
  102.     METHODS obtener_parametros
  103.       IMPORTING iv_programa          TYPE progname
  104.       RETURNING VALUE(rt_parametros) TYPE ty_t_parametros.
  105.     METHODS parametro
  106.       IMPORTING iv_nombre           TYPE rsscr_name
  107.                 iv_valor            TYPE clike
  108.       RETURNING VALUE(rs_parametro) TYPE rsparams.
  109.     METHODS lanzar_programa
  110.       IMPORTING iv_programa       TYPE progname
  111.                 it_parametros     TYPE ty_t_parametros
  112.       RETURNING VALUE(rt_detalle) TYPE string_table.
  113.     METHODS leer_lista_memoria
  114.       RETURNING VALUE(rt_lineas) TYPE string_table.
  115.     METHODS evaluar_memoria_global
  116.       CHANGING cs_paso TYPE ty_paso.
  117.  
  118.     " Lista de salida
  119.     METHODS mostrar_lista
  120.       IMPORTING it_pasos TYPE ty_t_pasos.
  121.     METHODS escribir_cabecera.
  122.     METHODS escribir_paso
  123.       IMPORTING is_paso TYPE ty_paso.
  124.     METHODS escribir_resumen
  125.       IMPORTING it_pasos TYPE ty_t_pasos.
  126. ENDCLASS.
  127.  
  128. CLASS lcl_limpiador IMPLEMENTATION.
  129.  
  130.   METHOD ejecutar.
  131.     " Validación: al menos una opción marcada
  132.     IF it_programas IS INITIAL.
  133.       MESSAGE 'Marque al menos una opción' TYPE 'S' DISPLAY LIKE 'E'.
  134.       RETURN.
  135.     ENDIF.
  136.  
  137.     " Se ejecutan en el orden recibido y se recoge el resultado de cada uno
  138.     DATA(lt_pasos) = VALUE ty_t_pasos( FOR ls_programa IN it_programas
  139.                                        ( procesar_paso( ls_programa ) ) ).
  140.  
  141.     mostrar_lista( lt_pasos ).
  142.   ENDMETHOD.
  143.  
  144.   METHOD procesar_paso.
  145.     rs_paso = VALUE #( programa    = is_programa-programa
  146.                        descripcion = is_programa-descripcion ).
  147.  
  148.     " 1. El programa debe existir en el sistema
  149.     IF existe_programa( is_programa-programa ) = abap_false.
  150.       rs_paso-estado  = gc_estado_error.
  151.       rs_paso-mensaje = 'El programa no existe en el sistema'.
  152.       RETURN.
  153.     ENDIF.
  154.  
  155.     " 2. Autorización previa: evita mensajes/popups del programa llamado
  156.     IF tiene_autorizacion( is_programa-programa ) = abap_false.
  157.       rs_paso-estado  = gc_estado_error.
  158.       rs_paso-mensaje = 'Sin autorización para ejecutar el programa'.
  159.       RETURN.
  160.     ENDIF.
  161.  
  162.     " 3. Limpieza de la memoria de retorno del GLOBAL
  163.     IF is_programa-programa = gc_prog_global.
  164.       FREE MEMORY ID gc_memid_glob.
  165.     ENDIF.
  166.  
  167.     " 4. Ejecución silenciosa midiendo la duración
  168.     GET RUN TIME FIELD DATA(lv_inicio).
  169.     rs_paso-detalle = lanzar_programa(
  170.                         iv_programa   = is_programa-programa
  171.                         it_parametros = obtener_parametros( is_programa-programa ) ).
  172.     GET RUN TIME FIELD DATA(lv_fin).
  173.  
  174.     rs_paso-segundos = ( lv_fin - lv_inicio ) / 1000000.
  175.     rs_paso-estado   = gc_estado_ok.
  176.     rs_paso-mensaje  = 'Ejecutado correctamente'.
  177.  
  178.     " 5. El GLOBAL devuelve sus errores en memoria ABAP
  179.     IF is_programa-programa = gc_prog_global.
  180.       evaluar_memoria_global( CHANGING cs_paso = rs_paso ).
  181.     ENDIF.
  182.   ENDMETHOD.
  183.  
  184.   METHOD existe_programa.
  185.     SELECT SINGLE name FROM trdir
  186.       INTO @DATA(lv_nombre)
  187.       WHERE name = @iv_programa.
  188.     rv_existe = xsdbool( sy-subrc = 0 ).
  189.   ENDMETHOD.
  190.  
  191.   METHOD tiene_autorizacion.
  192.     rv_ok = SWITCH #( iv_programa
  193.               WHEN gc_prog_bep THEN autorizacion_gateway( iv_clase = '/IWBEP/CL_COF_UTIL'
  194.                                                           iv_vista = '/IWBEP/I_MGW_CTC' )
  195.               WHEN gc_prog_fnd THEN autorizacion_gateway( iv_clase = '/IWFND/CL_COF_UTIL'
  196.                                                           iv_vista = '/IWFND/I_MED_CTC' )
  197.               WHEN gc_prog_ui5 THEN autorizacion_ui5( )
  198.               ELSE autorizacion_chip( ) ).
  199.   ENDMETHOD.
  200.  
  201.   METHOD autorizacion_chip.
  202.     " Comprobación de los programas /UI2/*
  203.     AUTHORITY-CHECK OBJECT '/UI2/CHIP'
  204.       ID '/UI2/CHIP' FIELD 'X-SAP-UI2*'
  205.       ID 'ACTVT'     FIELD '06'.
  206.     rv_ok = xsdbool( sy-subrc = 0 ).
  207.   ENDMETHOD.
  208.  
  209.   METHOD autorizacion_ui5.
  210.     " Comprobación de /UI5/APP_INDEX_CALCULATE (S_SUISUPRT o S_DEVELOP)
  211.     AUTHORITY-CHECK OBJECT 'S_SUISUPRT'
  212.       ID 'ACTVT'    FIELD '02'
  213.       ID 'SUI_AREA' FIELD 'UI5'.
  214.     IF sy-subrc = 0.
  215.       rv_ok = abap_true.
  216.       RETURN.
  217.     ENDIF.
  218.  
  219.     AUTHORITY-CHECK OBJECT 'S_DEVELOP'
  220.       ID 'DEVCLASS' DUMMY
  221.       ID 'OBJTYPE'  DUMMY
  222.       ID 'OBJNAME'  DUMMY
  223.       ID 'P_GROUP'  DUMMY
  224.       ID 'ACTVT'    FIELD '02'.
  225.     rv_ok = xsdbool( sy-subrc = 0 ).
  226.   ENDMETHOD.
  227.  
  228.   METHOD autorizacion_gateway.
  229.     " Llamada dinámica: evita dependencia de compilación con los
  230.     " componentes de Gateway; cualquier excepción = sin autorización
  231.     TRY.
  232.         CALL METHOD (iv_clase)=>('AUTHORITY_CHECK_CONFIG')
  233.           EXPORTING
  234.             iv_db_name          = iv_vista
  235.             iv_read_only_access = abap_true.
  236.         rv_ok = abap_true.
  237.       CATCH cx_root.
  238.         rv_ok = abap_false.
  239.     ENDTRY.
  240.   ENDMETHOD.
  241.  
  242.   METHOD obtener_parametros.
  243.     CASE iv_programa.
  244.       WHEN gc_prog_bep OR gc_prog_fnd.
  245.         " Limpiar todos los modelos
  246.         rt_parametros = VALUE #( ( parametro( iv_nombre = 'ALLMODEL' iv_valor = abap_true ) ) ).
  247.  
  248.       WHEN gc_prog_ui5.
  249.         " Todos los repositorios, modo "caducados" (por defecto 24 h).
  250.         " Se evita el modo 'recalcular todo' porque emite un aviso que
  251.         " forzaría a mostrar la pantalla de selección
  252.         rt_parametros = VALUE #( ( parametro( iv_nombre = 'P_ALL'   iv_valor = abap_true  ) )
  253.                                  ( parametro( iv_nombre = 'P_ALL_A' iv_valor = abap_false ) )
  254.                                  ( parametro( iv_nombre = 'P_ALL_D' iv_valor = abap_true  ) ) ).
  255.  
  256.       WHEN gc_prog_global.
  257.         " Modo ejecución
  258.         rt_parametros = VALUE #( ( parametro( iv_nombre = 'GV_TEST' iv_valor = abap_false ) )
  259.                                  ( parametro( iv_nombre = 'GV_EXE'  iv_valor = abap_true  ) ) ).
  260.  
  261.       WHEN gc_prog_client.
  262.         " Para todos los usuarios
  263.         rt_parametros = VALUE #( ( parametro( iv_nombre = 'GV_ALL'  iv_valor = abap_true  ) )
  264.                                  ( parametro( iv_nombre = 'GV_USER' iv_valor = abap_false ) ) ).
  265.  
  266.       WHEN OTHERS.
  267.         " /UI2/DELETE_CACHE_AFTER_IMP no tiene parámetros
  268.         CLEAR rt_parametros.
  269.     ENDCASE.
  270.   ENDMETHOD.
  271.  
  272.   METHOD parametro.
  273.     rs_parametro = VALUE #( selname = iv_nombre
  274.                             kind    = 'P'
  275.                             sign    = 'I'
  276.                             option  = 'EQ'
  277.                             low     = iv_valor ).
  278.   ENDMETHOD.
  279.  
  280.   METHOD lanzar_programa.
  281.     " Sin pantalla de selección; la lista se redirige a memoria
  282.     SUBMIT (iv_programa)
  283.       WITH SELECTION-TABLE it_parametros
  284.       EXPORTING LIST TO MEMORY
  285.       AND RETURN.
  286.  
  287.     " Se recupera la salida del estándar para mostrarla como detalle
  288.     rt_detalle = leer_lista_memoria( ).
  289.   ENDMETHOD.
  290.  
  291.   METHOD leer_lista_memoria.
  292.     DATA lt_lista TYPE STANDARD TABLE OF abaplist.
  293.  
  294.     CALL FUNCTION 'LIST_FROM_MEMORY'
  295.       TABLES
  296.         listobject = lt_lista
  297.       EXCEPTIONS
  298.         not_found  = 1
  299.         OTHERS     = 2.
  300.  
  301.     IF sy-subrc = 0 AND lt_lista IS NOT INITIAL.
  302.       CALL FUNCTION 'LIST_TO_ASCI'
  303.         EXPORTING
  304.           convert_symb_and_icon_2_text = abap_true
  305.         IMPORTING
  306.           list_string_ascii            = rt_lineas
  307.         TABLES
  308.           listobject                   = lt_lista
  309.         EXCEPTIONS
  310.           empty_list                   = 1
  311.           list_index_invalid           = 2
  312.           OTHERS                       = 3.
  313.       IF sy-subrc <> 0.
  314.         CLEAR rt_lineas.
  315.       ENDIF.
  316.     ENDIF.
  317.  
  318.     " Se libera siempre la memoria de lista
  319.     CALL FUNCTION 'LIST_FREE_MEMORY'.
  320.  
  321.     " Solo líneas con contenido, sin espacios sobrantes
  322.     LOOP AT rt_lineas ASSIGNING FIELD-SYMBOL(<lv_linea>).
  323.       <lv_linea> = condense( <lv_linea> ).
  324.     ENDLOOP.
  325.     DELETE rt_lineas WHERE table_line IS INITIAL.
  326.   ENDMETHOD.
  327.  
  328.   METHOD evaluar_memoria_global.
  329.     DATA lt_mensajes TYPE bapirettab.
  330.  
  331.     IMPORT msg = lt_mensajes FROM MEMORY ID gc_memid_glob.
  332.     FREE MEMORY ID gc_memid_glob.
  333.  
  334.     IF line_exists( lt_mensajes[ type = 'E' ] ).
  335.       cs_paso-estado  = gc_estado_error.
  336.       cs_paso-mensaje = 'Finalizado con errores'.
  337.       " Se añaden los textos de error al detalle
  338.       cs_paso-detalle = VALUE #( BASE cs_paso-detalle
  339.                                  FOR ls_mensaje IN lt_mensajes
  340.                                  WHERE ( type = 'E' )
  341.                                  ( CONV string( ls_mensaje-message ) ) ).
  342.     ENDIF.
  343.   ENDMETHOD.
  344.  
  345.   METHOD mostrar_lista.
  346.     escribir_cabecera( ).
  347.     LOOP AT it_pasos INTO DATA(ls_paso).
  348.       escribir_paso( ls_paso ).
  349.     ENDLOOP.
  350.     escribir_resumen( it_pasos ).
  351.   ENDMETHOD.
  352.  
  353.   METHOD escribir_cabecera.
  354.     FORMAT COLOR COL_HEADING INTENSIFIED ON.
  355.     WRITE: / |Limpieza de cachés Fiori / Gateway - Sistema { sy-sysid } / Mandante { sy-mandt }|,
  356.              AT sy-linsz space.
  357.     FORMAT COLOR COL_HEADING INTENSIFIED OFF.
  358.     WRITE: / |Usuario { sy-uname } - { sy-datum DATE = USER } { sy-uzeit TIME = USER }|,
  359.              AT sy-linsz space.
  360.     FORMAT RESET.
  361.     ULINE.
  362.   ENDMETHOD.
  363.  
  364.   METHOD escribir_paso.
  365.     " Línea principal: semáforo, programa, descripción, resultado, duración
  366.     DATA(lv_icono) = COND icon_d( WHEN is_paso-estado = gc_estado_ok
  367.                                   THEN icon_led_green
  368.                                   ELSE icon_led_red ).
  369.     DATA(lv_color) = COND i( WHEN is_paso-estado = gc_estado_ok
  370.                              THEN col_positive
  371.                              ELSE col_negative ).
  372.  
  373.     SKIP.
  374.     WRITE: / lv_icono AS ICON.
  375.     FORMAT COLOR = lv_color INTENSIFIED ON.
  376.     WRITE: (30) is_paso-programa,
  377.            (60) is_paso-descripcion,
  378.            (40) is_paso-mensaje,
  379.                 |{ is_paso-segundos } s|.
  380.     FORMAT RESET.
  381.  
  382.     " Detalle: salida capturada del programa estándar
  383.     IF is_paso-detalle IS INITIAL.
  384.       WRITE: /6 '(sin salida del programa)' COLOR COL_NORMAL INTENSIFIED OFF.
  385.       RETURN.
  386.     ENDIF.
  387.  
  388.     LOOP AT is_paso-detalle INTO DATA(lv_detalle).
  389.       WRITE: /6 lv_detalle COLOR COL_NORMAL INTENSIFIED OFF.
  390.     ENDLOOP.
  391.   ENDMETHOD.
  392.  
  393.   METHOD escribir_resumen.
  394.     DATA(lv_total)   = lines( it_pasos ).
  395.     DATA(lv_errores) = REDUCE i( INIT lv_n = 0
  396.                                  FOR ls_paso IN it_pasos
  397.                                  WHERE ( estado = gc_estado_error )
  398.                                  NEXT lv_n = lv_n + 1 ).
  399.  
  400.     SKIP.
  401.     ULINE.
  402.     IF lv_errores = 0.
  403.       FORMAT COLOR COL_POSITIVE INTENSIFIED ON.
  404.     ELSE.
  405.       FORMAT COLOR COL_NEGATIVE INTENSIFIED ON.
  406.     ENDIF.
  407.     WRITE: / |Programas ejecutados: { lv_total } - Correctos: { lv_total - lv_errores } - Con error: { lv_errores }|,
  408.              AT sy-linsz space.
  409.     FORMAT RESET.
  410.   ENDMETHOD.
  411.  
  412. ENDCLASS.
  413.  
  414. *----------------------------------------------------------------------*
  415. * Eventos
  416. *----------------------------------------------------------------------*
  417. INITIALIZATION.
  418.   gv_tit1 = 'Gateway / SAPUI5'.
  419.   gv_tbep = 'Caché de metadatos backend (/IWBEP/CACHE_CLEANUP)'.
  420.   gv_tfnd = 'Caché de metadatos Gateway Hub (/IWFND/CACHE_CLEANUP)'.
  421.   gv_tui5 = 'Recalcular índice de apps SAPUI5 (puede tardar)'.
  422.   gv_tit2 = 'Fiori Launchpad (UI2)'.
  423.   gv_tglo = 'Invalidar cachés globales (modo ejecución)'.
  424.   gv_timp = 'Borrar caché UI2 de todos los mandantes (after import)'.
  425.   gv_tcli = 'Invalidar cachés de cliente (todos los usuarios)'.
  426.  
  427. START-OF-SELECTION.
  428.   " Programas marcados, en el orden de ejecución recomendado
  429.   DATA(gt_programas) = VALUE lcl_limpiador=>ty_t_programas(
  430.     ( LINES OF COND #( WHEN p_bep = abap_true
  431.                        THEN VALUE #( ( programa = gc_prog_bep descripcion = gv_tbep ) ) ) )
  432.     ( LINES OF COND #( WHEN p_fnd = abap_true
  433.                        THEN VALUE #( ( programa = gc_prog_fnd descripcion = gv_tfnd ) ) ) )
  434.     ( LINES OF COND #( WHEN p_ui5 = abap_true
  435.                        THEN VALUE #( ( programa = gc_prog_ui5 descripcion = gv_tui5 ) ) ) )
  436.     ( LINES OF COND #( WHEN p_global = abap_true
  437.                        THEN VALUE #( ( programa = gc_prog_global descripcion = gv_tglo ) ) ) )
  438.     ( LINES OF COND #( WHEN p_imp = abap_true
  439.                        THEN VALUE #( ( programa = gc_prog_imp descripcion = gv_timp ) ) ) )
  440.     ( LINES OF COND #( WHEN p_client = abap_true
  441.                        THEN VALUE #( ( programa = gc_prog_client descripcion = gv_tcli ) ) ) ) ).
  442.  
  443.   NEW lcl_limpiador( )->ejecutar( gt_programas ).

SAP : ABAP : FIORI : UI2 : UI5 : Programación

Última modificación de la página el 05 November 2026 a las 08h26
Powered by PmWiki